; Installer script for ClipHandler
; $VER: Install ClipHandler 37.3 (21.11.95)

(complete 0)

(set @l-dest "L:")
(set @permanent-dest "DEVS:DOSDrivers/")
(set @default-dest "SYS:Storage/DOSDrivers/")

(set #handler "L/clip-handler")
(set #driver "Devs/DOSDrivers/")

; ***************************************************************************
; English strings

(set #bad-kick
	(cat "You must have AmigaDOS 2.04 or higher to use ClipHandler!"))

(set #welcome
	(cat "\nClipHandler installation\n\n\n"
       "This script installs ClipHandler 1.2\n"
       "on your Amiga.\n\n\n\n"
       "ClipHandler is\n"
       "Copyright  1995 Michal Letowski\n"
       "All rights reserved.\n\n"))

(set #where-driver
	(cat "Should ClipHandler be installed permanently?"))

(set #where-help
	(cat "\nDOS devices can be installed permanently"
	     " (they are mounted on each reboot)\n"
       " or non-permanently (so they can be mounted at"
       " any time.)\n"))

; ***************************************************************************
; Install ClipHan

; Check AmigaDOS version
(set #version (/ (getversion) 65536))
(if (< #version 37)
	(
		(abort #bad-kick)
	)
)

(message #welcome)

(welcome)
(set old_level @user-level)

(user 2)
(set #perm
	(askbool
		(prompt #where-driver)
		(help #where-help)
		(default 0))
)
(if #perm
	(set @driver-dest @permanent-dest)
	(set @driver-dest @default-dest)
)

; Do copy
(user old_level)

; Copy handler
(copylib
	(source #handler)
	(dest @l-dest)
)
(complete 50)

; Copy DOSDriver
(copyfiles
	(source #driver)
	(dest @driver-dest)
	(all)
)
(complete 100)

(set @default-dest "")
(exit)
